PrtMip 屬性
內容
在 Visual Basic 中使用 PrtMip 屬性可以設置或返回“打印”對話框中針對窗體或報表指定的設備模式信息。
expression.PrtMip
expression 必需。返回“應用于”列表中的一個對象的表達式。
說明
PrtMip 屬性設置是一個 28 字節(jié)的結構，對應的是“頁面設置”對話框的“邊距”選項卡中對窗體或報表的設置。
PrtMip 屬性有以下成員：
成員 |
說明 |
LeftMargin、RightMargin、TopMargin、BottomMargin |
|
DataOnly |
指定打印元素的 Long 值。為 True 時，只打印“數據表”視圖、窗體或報表中的表數據或查詢數據，不打印標簽、控件的邊框和網格線，而且顯示諸如線條和方框等圖形。為 False 時，打印數據、標簽及圖形。 |
ItemsAcross |
Long 值，用于指定多列報表或標簽中的列數。該成員與“頁面設置”對話框“列”選項卡中“網格設置”下的“列數”框的值是相等的。 |
RowSpacing |
Long 值，以磅的 1/20 為單位，指定主體節(jié)間的水平間距。 |
ColumnSpacing |
Long 值，以緹為單位，指定主體節(jié)間的垂直間距。 |
DefaultSize |
Long 值。為 True 時，使用“設計”視圖中主體節(jié)的大??；為 False 時，使用 ItemSizeWidth 和 ItemSizeHeight 成員指定的值。 |
ItemSizeWidth |
Long 值，以緹為單位，指定主體節(jié)的寬度。該成員與“頁面設置”對話框“列”選項卡中“列尺寸”下的“寬度”框的值相同。 |
ItemSizeHeight |
Long 值，以緹為單位，指定主體節(jié)的寬度。該成員與“頁面設置”對話框“列”選項卡中“列尺寸”下的“高度”框的值相等。 |
ItemLayout |
Long 值，用于指定水平 (1953) 或垂直 (1954) 的列布局。該成員與“頁面設置”對話框“列”選項卡中“列布局”下的“先行后列”或“先列后行”選項分別相同。 |
FastPrint |
保留。 |
Datasheet |
保留。 |
PrtMip 屬性設置在“設計”視圖中可讀寫，而在其他視圖中則為只讀。
示例
下面的 PrtMip 屬性示例演示如何設置具有兩個水平列的報表。
Private Type str_PRTMIP
strRGB As String * 28
End Type
Private Type type_PRTMIP
xLeftMargin As Long
yTopMargin As Long
xRightMargin As Long
yBotMargin As Long
fDataOnly As Long
xWidth As Long
yHeight As Long
fDefaultSize As Long
cxColumns As Long
yColumnSpacing As Long
xRowSpacing As Long
rItemLayout As Long
fFastPrint As Long
fDatasheet As Long
End Type
Public Sub PrtMipCols(ByVal strName As String)
Dim PrtMipString As str_PRTMIP
Dim PM As type_PRTMIP
Dim rpt As Report
Const PM_HORIZONTALCOLS = 1953
Const PM_VERTICALCOLS = 1954
' Open the report.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
PrtMipString.strRGB = rpt.PrtMip
LSet PM = PrtMipString
' Create two columns.
PM.cxColumns = 2
' Set 0.25 inch between rows.
PM.xRowSpacing = 0.25 * 1440
' Set 0.5 inch between columns.
PM.yColumnSpacing = 0.5 * 1440
PM.rItemLayout = PM_HORIZONTALCOLS
' Update property.
LSet PrtMipString = PM
rpt.PrtMip = PrtMipString.strRGB
Set rpt = Nothing
End Sub
下一個 PrtMip 屬性示例顯示如何將全部頁邊距設為 1 英寸。
Public Sub SetMarginsToDefault(ByVal strName As String)
Dim PrtMipString As str_PRTMIP
Dim PM As type_PRTMIP
Dim rpt As Report
' Open the report.
DoCmd.OpenReport strName, acDesign
Set rpt = Reports(strName)
PrtMipString.strRGB = rpt.PrtMip
LSet PM = PrtMipString
' Set margins.
PM.xLeftMargin = 1 * 1440
PM.yTopMargin = 1 * 1440
PM.xRightMargin = 1 * 1440
PM.yBotMargin = 1 * 1440
' Update property.
LSet PrtMipString = PM
rpt.PrtMip = PrtMipString.strRGB
Set rpt = Nothing
End Sub