設(shè)為首頁收藏本站Access中國

Office中國論壇/Access中國論壇

 找回密碼
 注冊

QQ登錄

只需一步，快速開始

返回列表 發(fā)新帖
查看: 7865|回復(fù): 9
打印 上一主題 下一主題

一個用戶管理的數(shù)據(jù)庫腳本

[復(fù)制鏈接]

點擊這里給我發(fā)消息
跳轉(zhuǎn)到指定樓層
1#
發(fā)表于 2012-1-13 02:06:51 | 只看該作者 回帖獎勵 |倒序瀏覽 |閱讀模式
想寫一個通用的用戶管理數(shù)據(jù)庫，因此，今天寫了如下 T-SQL 腳本，練習自己的寫腳本能力。現(xiàn)在放在這里，也許對一些網(wǎng)友有作用。呵呵......



2012-01-12
朱亦文
  1. ---=========================================================================---
  2. --- 創(chuàng)建 [Person] 數(shù)據(jù)庫
  3. --- 日期：2011-01-12
  4. ---=========================================================================---
  5. USE [master]
  6. GO

  8. IF EXISTS (SELECT name FROM master.dbo.sysdatabases WHERE name = N'Person')
  9. DROP DATABASE [Person]
  10. GO

  12. CREATE DATABASE [Person] ON
  13. (
  14.         NAME = N'Person',
  15.         FILENAME = N'D:\DB\Person\Person.mdf',
  16.         SIZE = 1024KB,
  17.         MAXSIZE = UNLIMITED,
  18.         FILEGROWTH = 1024KB
  19. )
  20. LOG ON
  21. (
  22.         NAME = N'Person_log',
  23.         FILENAME = N'D:\DB\Person\Person_log.ldf',
  24.         SIZE = 1024KB,
  25.         MAXSIZE = UNLIMITED,
  26.         FILEGROWTH = 1024KB
  27. )
  28. GO

  30. USE [Person]
  31. GO


  34. ---=========================================================================---
  35. --- 創(chuàng)建表
  36. ---=========================================================================---
  37. GO

  39. --------------------------------------------------
  40. --- 表  ：USysUsers
  41. --- 用途：存儲用戶
  42. --------------------------------------------------
  43. CREATE TABLE [dbo].[USysUsers](
  44.         [UID] [int] IDENTITY(1000,1) NOT NULL,
  45.         [UserName] [nvarchar](50) NOT NULL,
  46.         [Password] [varchar](256) NOT NULL DEFAULT (''),
  47.         [IsSystem] [bit] NOT NULL DEFAULT (0),
  48.         [Description] [nvarchar](256) NULL,
  49.         [Enabled] [bit] NOT NULL DEFAULT (1),
  50.         [CreateTime] [datetime] NOT NULL DEFAULT (getdate()),
  51.         CONSTRAINT [PK_USysUsers] PRIMARY KEY CLUSTERED
  52.         (
  53.                 [UID] ASC
  54.         ),
  55.         CONSTRAINT [IX_USysUsers] UNIQUE NONCLUSTERED
  56.         (
  57.                 [UserName] ASC
  58.         )
  59. )
  60. GO

  62. --- 創(chuàng)建系統(tǒng)帳戶
  63. SET IDENTITY_INSERT [dbo].[USysUsers] ON
  64. GO
  65. INSERT [dbo].[USysUsers]
  66.         ([UID],[UserName],[Password],[IsSystem],[Description],[Enabled]) VALUES
  67.         (0, N'Guest',                        '',                1, N'匿名來賓用戶',        0)
  68. INSERT [dbo].[USysUsers]
  69.         ([UID],[UserName],[Password],[IsSystem],[Description],[Enabled]) VALUES
  70.         (1, N'Administrator',        'sys',        1, N'系統(tǒng)管理員',        1)
  71. GO
  72. SET IDENTITY_INSERT [dbo].[USysUsers] OFF
  73. GO

  75. --------------------------------------------------
  76. --- 函數(shù)：fbUSysGeustIsEnabled
  77. --- 目的：判定是否允許匿名來賓用戶
  78. --- 返回：0 - 不允許，1 - 允許
  79. --- 依賴：dbo.USysUsers
  80. --------------------------------------------------
  81. CREATE FUNCTION [dbo].[fbUSysGeustIsEnabled]()
  82. RETURNS bit
  83. AS
  84. BEGIN
  85.         DECLARE @ret bit

  87.         -- 從[dbo].[USysUsers]表中獲取 Guest 用戶啟用
  88.         -- 作為系統(tǒng)是否允許匿名
  89.         SELECT @ret = [Enabled] FROM [dbo].[USysUsers] WHERE [UID] = 0

  91.         IF @ret IS NULL
  92.                 SET @ret = 0

  94.         RETURN @ret
  95. END
  96. GO

  98. --------------------------------------------------
  99. --- 過程：_paUSysSetUserEnabled
  100. --- 目的：設(shè)置用戶是否啟用
  101. --- 參數(shù)：
  102. ---                @UID - 用戶 ID
  103. ---                @Enabled - 0-不允許，1-允許
  104. --- 返回：0 - 不成功
  105. --- 依賴：dbo.USysUsers
  106. --------------------------------------------------
  107. CREATE PROCEDURE [dbo].[_paUSysSetUserEnabled]
  108. (
  109.         @UID int,
  110.         @Enabled bit
  111. )
  112. AS
  113. BEGIN
  114.         IF @Enabled IS NOT NULL
  115.                 UPDATE [dbo].[USysUsers]
  116.                 SET Enabled = @Enabled
  117.                 WHERE UID = @UID

  119.         RETURN @@ROWCOUNT
  120. END
  121. GO

  123. --------------------------------------------------
  124. --- 過程：paUserDisableGuest
  125. --- 目的：停用匿名用戶
  126. --- 返回：0 - 不成功
  127. --- 依賴：dbo.USysUsers/dbo._paUSysSetUserEnabled
  128. --------------------------------------------------
  129. CREATE PROCEDURE [dbo].[paUserDisableGuest]
  130. AS
  131. BEGIN
  132.         DECLARE        @return_value int
  133.         EXEC        @return_value = [dbo].[_paUSysSetUserEnabled]
  134.                         @UID = 0,
  135.                         @Enabled = 0

  137.         RETURN @return_value
  138. END
  139. GO

  141. --------------------------------------------------
  142. --- 過程：paUserEnableGuest
  143. --- 目的：啟用匿名用戶
  144. --- 返回：0 - 不成功
  145. --- 依賴：dbo.USysUsers/dbo._paUSysSetUserEnabled
  146. --------------------------------------------------
  147. CREATE PROCEDURE [dbo].[paUserEnableGuest]
  148. AS
  149. BEGIN
  150.         DECLARE        @return_value int
  151.         EXEC        @return_value = [dbo].[_paUSysSetUserEnabled]
  152.                         @UID = 0,
  153.                         @Enabled = 1

  155.         RETURN @return_value
  156. END
  157. GO

  159. --------------------------------------------------
  160. --- 過程：paUserDisableUser
  161. --- 目的：停用用戶
  162. --- 返回：0 - 不成功
  163. --- 依賴：dbo.USysUsers/dbo._paUSysSetUserEnabled
  164. --------------------------------------------------
  165. CREATE PROCEDURE [dbo].[paUserDisableUser](@UID int)
  166. AS
  167. BEGIN
  168.         DECLARE        @return_value int
  169.         EXEC        @return_value = [dbo].[_paUSysSetUserEnabled]
  170.                         @UID = @UID,
  171.                         @Enabled = 0

  173.         RETURN @return_value
  174. END
  175. GO

  177. --------------------------------------------------
  178. --- 過程：paUserEnableUser
  179. --- 目的：啟用用戶
  180. --- 返回：0 - 不成功
  181. --- 依賴：dbo.USysUsers/dbo._paUSysSetUserEnabled
  182. --------------------------------------------------
  183. CREATE PROCEDURE [dbo].[paUserEnableUser](@UID int)
  184. AS
  185. BEGIN
  186.         DECLARE        @return_value int
  187.         EXEC        @return_value = [dbo].[_paUSysSetUserEnabled]
  188.                         @UID = @UID,
  189.                         @Enabled = 1

  191.         RETURN @return_value
  192. END
  193. GO

  195. --------------------------------------------------
  196. --- 表  ：USysUserExtender
  197. --- 用途：存儲用戶擴展屬性
  198. --- 依賴：dbo.USysUsers
  199. --------------------------------------------------
  200. CREATE TABLE [dbo].[USysUserExtender](
  201.         [UID] [int] NOT NULL,
  202.         [RealName] [nvarchar](50) NULL,
  203.         [Gender] [nchar](1) NULL,
  204.         [Birthday] [datetime] NULL,
  205.         [Email] [nvarchar](256) NULL,
  206.         [Company] [nvarchar](50) NULL,
  207.         [Post] [nvarchar](10) NULL,                /* 職位/崗位/職務(wù) */
  208.         [Title] [nvarchar](10) NULL,        /* 稱謂/頭銜/職稱 */
  209.         [Mobile] [varchar](50) NULL,
  210.         [Tel] [varchar](50) NULL,
  211.         [Province] [nvarchar](10) NULL,
  212.         [City] [nvarchar](10) NULL,
  213.         [ZipCode] [varchar](6) NULL,
  214.         CONSTRAINT [PK_USysUserExtender] PRIMARY KEY CLUSTERED
  215.         (
  216.                 [UID] ASC
  217.         )
  218. )
  219. GO

  221. --- 設(shè)置 USysUserExtender 與 USysUsers 關(guān)系
  222. --- 級聯(lián)更新、級聯(lián)刪除
  223. ALTER TABLE [dbo].[USysUserExtender]
  224.         WITH
  225.                 CHECK ADD CONSTRAINT [FK_USysUserExtender_USysUsers]
  226.                         FOREIGN KEY([UID]) REFERENCES [dbo].[USysUsers] ([UID])
  227.                         ON UPDATE CASCADE
  228.                         ON DELETE CASCADE
  229. GO

  231. --------------------------------------------------
  232. --- 函數(shù)：_ftUSysUsers
  233. --- 用途：獲取用戶列表
  234. --- 依賴：dbo.USysUsers/dbo.USysUserExtender
  235. --------------------------------------------------
  236. CREATE FUNCTION [dbo].[_ftUSysUsers]
  237. (       
  238.         @System bit = NULL,
  239.         @Enabled bit = NULL
  240. )
  241. RETURNS TABLE
  242. AS
  243. RETURN
  244. (
  245.         SELECT
  246.                 u.UID,
  247.                 u.UserName,
  248.                 u.Password,
  249.                 u.IsSystem,
  250.                 u.Description,
  251.                 u.CreateTime,
  252.                 e.RealName,
  253.                 e.Gender,
  254.                 e.Birthday,
  255.                 e.Email,
  256.                 e.Company,
  257.                 e.Post,
  258.                 e.Title,
  259.                 e.Mobile,
  260.                 e.Tel,
  261.                 e.Province,
  262.                 e.City,
  263.                 e.ZipCode
  264.         FROM
  265.                 dbo.USysUsers AS u LEFT OUTER JOIN
  266.                 dbo.USysUserExtender AS e ON u.UID = e.UID
  267.         WHERE
  268.                 ((u.Enabled = @Enabled) OR (@Enabled IS NULL)) AND
  269.                 ((u.IsSystem = @System) OR (@System IS NULL))
  270. )
  271. GO

  273. --------------------------------------------------
  274. --- 視圖：vUsersAll
  275. --- 用途：所有用戶
  276. --- 依賴：dbo.USysUsers/dbo.USysUserExtender/dbo._ftUSysUsers
  277. --------------------------------------------------
  278. CREATE VIEW [dbo].[vUsersAll]
  279. AS
  280. SELECT * FROM [dbo].[_ftUSysUsers](NULL, NULL)
  281. GO

  283. --------------------------------------------------
  284. --- 視圖：vUsersSystem
  285. --- 用途：所有系統(tǒng)用戶
  286. --- 依賴：dbo.USysUsers/dbo.USysUserExtender/dbo._ftUSysUsers
  287. --------------------------------------------------
  288. CREATE VIEW [dbo].[vUsersSystem]
  289. AS
  290. SELECT * FROM [dbo].[_ftUSysUsers](1, NULL)
  291. GO

  293. --------------------------------------------------
  294. --- 視圖：vUsersSystemCurrent
  295. --- 用途：當前系統(tǒng)用戶
  296. --- 依賴：dbo.USysUsers/dbo.USysUserExtender/dbo._ftUSysUsers
  297. --------------------------------------------------
  298. CREATE VIEW [dbo].[vUsersSystemCurrent]
  299. AS
  300. SELECT * FROM [dbo].[_ftUSysUsers](1, 1)
  301. GO

  303. --------------------------------------------------
  304. --- 視圖：vUsersSystemDisabled
  305. --- 用途：當前禁用的系統(tǒng)用戶
  306. --- 依賴：dbo.USysUsers/dbo.USysUserExtender/dbo._ftUSysUsers
  307. --------------------------------------------------
  308. CREATE VIEW [dbo].[vUsersSystemDisabled]
  309. AS
  310. SELECT * FROM [dbo].[_ftUSysUsers](1, 0)
  311. GO

  313. --------------------------------------------------
  314. --- 視圖：vUsersGeneral
  315. --- 用途：所有一般用戶
  316. --- 依賴：dbo.USysUsers/dbo.USysUserExtender/dbo._ftUSysUsers
  317. --------------------------------------------------
  318. CREATE VIEW [dbo].[vUsersGeneral]
  319. AS
  320. SELECT * FROM [dbo].[_ftUSysUsers](0, NULL)
  321. GO

  323. --------------------------------------------------
  324. --- 視圖：vUsersGeneralCurrent
  325. --- 用途：當前一般用戶
  326. --- 依賴：dbo.USysUsers/dbo.USysUserExtender/dbo._ftUSysUsers
  327. --------------------------------------------------
  328. CREATE VIEW [dbo].[vUsersGeneralCurrent]
  329. AS
  330. SELECT * FROM [dbo].[_ftUSysUsers](0, 1)
  331. GO

  333. --------------------------------------------------
  334. --- 視圖：vUsersGeneralDisabled
  335. --- 用途：當前禁用的一般用戶
  336. --- 依賴：dbo.USysUsers/dbo.USysUserExtender/dbo._ftUSysUsers
  337. --------------------------------------------------
  338. CREATE VIEW [dbo].[vUsersGeneralDisabled]
  339. AS
  340. SELECT * FROM [dbo].[_ftUSysUsers](0, 0)
  341. GO
復(fù)制代碼

本帖子中包含更多資源

您需要 登錄 才可以下載或查看，沒有帳號？注冊

x

本帖被以下淘專輯推薦:

分享到:  QQ好友和群QQ好友和群 QQ空間QQ空間 騰訊微博騰訊微博 騰訊朋友騰訊朋友
收藏收藏2 分享分享 分享淘帖2 訂閱訂閱

點擊這里給我發(fā)消息
2#
 樓主| 發(fā)表于 2012-1-13 02:07:27 | 只看該作者
  1. --------------------------------------------------
  2. --- 過程：paUsersAdd
  3. --- 用途：增加新用戶
  4. --- 返回：0-不成功
  5. --- 依賴：dbo.USysUsers
  6. --------------------------------------------------
  7. CREATE PROCEDURE [dbo].[paUsersAdd]
  8. (
  9.         @UID int OUTPUT,                                /* 用戶ID 輸出新增自動產(chǎn)生 */
  10.         @UserName nvarchar(50),                        /* 用戶名 */
  11.         @Password varchar(256),                        /* 密碼 */
  12.         @Description nvarchar(256),                /* 描述 */
  13.         @IsSystem bit = 0,                                /* 是否系統(tǒng)用戶 0-普通用戶，1-系統(tǒng)用戶 */
  14.         @Enabled bit = 1                                /* 是否啟用 0-停用，1-啟用 */
  15. )
  16. AS
  17. BEGIN
  18.         DECLARE @ret int

  20.         INSERT INTO [dbo].[USysUsers]
  21.                            ([UserName]
  22.                            ,[Password]
  23.                            ,[IsSystem]
  24.                            ,[Description]
  25.                            ,[Enabled])
  26.                  VALUES
  27.                            (@UserName
  28.                            ,@Password
  29.                            ,@IsSystem
  30.                            ,@Description
  31.                            ,@Enabled)

  33.         IF @@ROWCOUNT >0
  34.                 SET @ret = SCOPE_IDENTITY( )
  35.         ELSE
  36.                 SET @ret = 0

  38.         SET @UID = @ret
  39.        
  40.         RETURN @ret
  41. END
  42. GO

  44. --------------------------------------------------
  45. --- 過程：paUserChangePassword
  46. --- 用途：更改用戶密碼
  47. --- 返回：0-不成功
  48. --- 依賴：dbo.USysUsers
  49. --------------------------------------------------
  50. CREATE PROCEDURE [dbo].[paUserChangePassword]
  51. (
  52.         @UID int,                                /* 用戶ID */
  53.         @Password varchar(256)        /* 密碼 */
  54. )
  55. AS
  56. BEGIN
  57.         UPDATE        [dbo].[USysUsers]
  58.         SET                [Password] = @Password
  59.         WHERE        [UID] = @UID

  61.         RETURN @@ROWCOUNT
  62. END
  63. GO

  65. --------------------------------------------------
  66. --- 過程：paUserChangeDescription
  67. --- 用途：更改用戶描述
  68. --- 返回：0-不成功
  69. --- 依賴：dbo.USysUsers
  70. --------------------------------------------------
  71. CREATE PROCEDURE [dbo].[paUserChangeDescription]
  72. (
  73.         @UID int,                                        /* 用戶ID */
  74.         @Description varchar(256)        /* 描述 */
  75. )
  76. AS
  77. BEGIN
  78.         UPDATE        [dbo].[USysUsers]
  79.         SET                [Description] = @Description
  80.         WHERE        [UID] = @UID

  82.         RETURN @@ROWCOUNT
  83. END
  84. GO

  86. --------------------------------------------------
  87. --- 過程：paUserChangeUserName
  88. --- 用途：更改用戶名
  89. --- 返回：0-不成功
  90. --- 依賴：dbo.USysUsers
  91. --------------------------------------------------
  92. CREATE PROCEDURE [dbo].[paUserChangeUserName]
  93. (
  94.         @UID int,                                /* 用戶ID */
  95.         @UserName nvarchar(50)        /* 用戶名 */
  96. )
  97. AS
  98. BEGIN
  99.         UPDATE        [dbo].[USysUsers]
  100.         SET                [UserName] = @UserName
  101.         WHERE        [UID] = @UID

  103.         RETURN @@ROWCOUNT
  104. END
  105. GO

  107. --------------------------------------------------
  108. --- 過程：paUserEditExtender
  109. --- 用途：修改用戶擴展屬性
  110. --- 返回：0-不成功
  111. --- 依賴：dbo.USysUserExtender
  112. --------------------------------------------------
  113. CREATE PROCEDURE [dbo].[paUserEditExtender]
  114. (
  115.         @UID                int,
  116.         @RealName        nvarchar(50)        = NULL,
  117.         @Gender                nchar(1)                = NULL,
  118.         @Birthday        datetime                = NULL,
  119.         @Email                nvarchar(256)        = NULL,
  120.         @Company        nvarchar(50)        = NULL,
  121.         @Post                nvarchar(10)        = NULL,
  122.         @Title                nvarchar(10)        = NULL,
  123.         @Mobile                varchar(50)                = NULL,
  124.         @Tel                varchar(50)                = NULL,
  125.         @Province        nvarchar(10)        = NULL,
  126.         @City                nvarchar(10)        = NULL,
  127.         @ZipCode        varchar(6)                = NULL
  128. )
  129. AS
  130. BEGIN
  131.         IF EXISTS (SELECT [UID] FROM [dbo].[USysUserExtender] WHERE [UID] = @UID)
  132.                 UPDATE [dbo].[USysUserExtender]
  133.                    SET [RealName]        = @RealName
  134.                           ,[Gender]                = @Gender
  135.                           ,[Birthday]        = @Birthday
  136.                           ,[Email]                = @Email
  137.                           ,[Company]        = @Company
  138.                           ,[Post]                = @Post
  139.                           ,[Title]                = @Title
  140.                           ,[Mobile]                = @Mobile
  141.                           ,[Tel]                = @Tel
  142.                           ,[Province]        = @Province
  143.                           ,[City]                = @City
  144.                           ,[ZipCode]        = @ZipCode
  145.                  WHERE [UID] = @UID
  146.         ELSE
  147.                 INSERT INTO [dbo].[USysUserExtender]
  148.                         ([UID],[RealName],[Gender],[Birthday],[Email],[Company],[Post],[Title],[Mobile],[Tel],[Province],[City],[ZipCode])
  149.                          VALUES
  150.                         (
  151.                                 @UID,
  152.                                 @RealName,
  153.                                 @Gender,
  154.                                 @Birthday,
  155.                                 @Email,
  156.                                 @Company,
  157.                                 @Post,
  158.                                 @Title,
  159.                                 @Mobile,
  160.                                 @Tel,
  161.                                 @Province,
  162.                                 @City,
  163.                                 @ZipCode
  164.                         )

  166.         RETURN @@ROWCOUNT
  167. END
  168. GO

  170. --------------------------------------------------
  171. --- 過程：paUserSetExtender
  172. --- 用途：設(shè)置用戶擴展屬性
  173. --- 返回：0-不成功
  174. --- 依賴：dbo.USysUserExtender
  175. --------------------------------------------------
  176. CREATE PROCEDURE [dbo].[paUserSetExtender]
  177. (
  178.         @UID                        int,
  179.         @ExtenderName        sysname,
  180.         @Value                        sql_variant        = NULL
  181. )
  182. AS
  183. BEGIN
  184.         DECLARE @ret int
  185.         SET @ret = 0

  187.         IF NOT EXISTS (SELECT [UID] FROM [dbo].[USysUserExtender] WHERE [UID] = @UID)
  188.                 INSERT INTO [dbo].[USysUserExtender] ([UID]) VALUES (@UID)

  190.         IF @@ERROR = 0
  191.                 BEGIN
  192.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('RealName')
  193.                                 BEGIN
  194.                                         UPDATE [dbo].[USysUserExtender] SET [RealName]        = CAST(@Value AS nvarchar(50)) WHERE [UID] = @UID
  195.                                         SET @ret = @ret + @@ROWCOUNT
  196.                                 END
  197.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('Gender')
  198.                                 BEGIN
  199.                                         UPDATE [dbo].[USysUserExtender] SET [Gender]        = CAST(@Value AS nchar(1)) WHERE [UID] = @UID
  200.                                         SET @ret = @ret + @@ROWCOUNT
  201.                                 END
  202.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('Birthday')
  203.                                 BEGIN
  204.                                         UPDATE [dbo].[USysUserExtender] SET [Birthday]        = CAST(@Value AS datetime) WHERE [UID] = @UID
  205.                                         SET @ret = @ret + @@ROWCOUNT
  206.                                 END
  207.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('Email')
  208.                                 BEGIN
  209.                                         UPDATE [dbo].[USysUserExtender] SET [Email]                = CAST(@Value AS nvarchar(256)) WHERE [UID] = @UID
  210.                                         SET @ret = @ret + @@ROWCOUNT
  211.                                 END
  212.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('Company')
  213.                                 BEGIN
  214.                                         UPDATE [dbo].[USysUserExtender] SET [Company]        = CAST(@Value AS nvarchar(50)) WHERE [UID] = @UID
  215.                                         SET @ret = @ret + @@ROWCOUNT
  216.                                 END
  217.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('Post')
  218.                                 BEGIN
  219.                                         UPDATE [dbo].[USysUserExtender] SET [Post]                = CAST(@Value AS nvarchar(10)) WHERE [UID] = @UID
  220.                                         SET @ret = @ret + @@ROWCOUNT
  221.                                 END
  222.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('Title')
  223.                                 BEGIN
  224.                                         UPDATE [dbo].[USysUserExtender] SET [Title]                = CAST(@Value AS nvarchar(10)) WHERE [UID] = @UID
  225.                                         SET @ret = @ret + @@ROWCOUNT
  226.                                 END
  227.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('Mobile')
  228.                                 BEGIN
  229.                                         UPDATE [dbo].[USysUserExtender] SET [Mobile]        = CAST(@Value AS varchar(50)) WHERE [UID] = @UID
  230.                                         SET @ret = @ret + @@ROWCOUNT
  231.                                 END
  232.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('Tel')
  233.                                 BEGIN
  234.                                         UPDATE [dbo].[USysUserExtender] SET [Tel]                = CAST(@Value AS varchar(50)) WHERE [UID] = @UID
  235.                                         SET @ret = @ret + @@ROWCOUNT
  236.                                 END
  237.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('Province')
  238.                                 BEGIN
  239.                                         UPDATE [dbo].[USysUserExtender] SET [Province]        = CAST(@Value AS nvarchar(10)) WHERE [UID] = @UID
  240.                                         SET @ret = @ret + @@ROWCOUNT
  241.                                 END
  242.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('City')
  243.                                 BEGIN
  244.                                         UPDATE [dbo].[USysUserExtender] SET [City]                = CAST(@Value AS nvarchar(10)) WHERE [UID] = @UID
  245.                                         SET @ret = @ret + @@ROWCOUNT
  246.                                 END
  247.                         IF UPPER(RTRIM(@ExtenderName)) = UPPER('ZipCode')
  248.                                 BEGIN
  249.                                         UPDATE [dbo].[USysUserExtender] SET [ZipCode]        = CAST(@Value AS varchar(6)) WHERE [UID] = @UID
  250.                                         SET @ret = @ret + @@ROWCOUNT
  251.                                 END
  252.                 END

  254.         RETURN @ret
  255. END
  256. GO
復(fù)制代碼
3#
發(fā)表于 2012-1-13 07:15:04 | 只看該作者
先頂 再頂 我頂頂頂{:soso_e112:}
終于住一樓了
4#
發(fā)表于 2012-1-13 08:17:08 | 只看該作者
謝謝分享收藏了

點擊這里給我發(fā)消息
5#
發(fā)表于 2012-1-14 09:23:35 | 只看該作者
謝謝老朱分享

點擊這里給我發(fā)消息
6#
 樓主| 發(fā)表于 2012-1-15 20:07:22 | 只看該作者
2012-01-15 新增
  1. --------------------------------------------------
  2. --- 過程：paUsersDel
  3. --- 用途：刪除指定用戶
  4. --- 返回：0-不成功
  5. --- 依賴：dbo.USysUsers
  6. --------------------------------------------------
  7. CREATE PROCEDURE [dbo].[paUsersDel]
  8. (
  9.         @UID int
  10. )
  11. AS
  12. BEGIN
  13.         DELETE [dbo].[USysUsers] WHERE [UID] = @UID

  15.         RETURN @@ROWCOUNT
  16. END
  17. GO
復(fù)制代碼
7#
發(fā)表于 2012-1-15 22:03:02 | 只看該作者
朱大哥現(xiàn)在用sql2008了?

點擊這里給我發(fā)消息
8#
 樓主| 發(fā)表于 2012-1-15 22:42:27 | 只看該作者
沒有，那個太龐大了，朱大哥用不起，呵呵。
9#
發(fā)表于 2012-1-17 10:15:04 | 只看該作者
謝謝分享

先復(fù)制,偶功力太淺要慢慢研究
10#
發(fā)表于 2012-1-31 10:10:10 | 只看該作者
{:soso_e179:}學習
您需要登錄后才可以回帖 登錄 | 注冊

本版積分規(guī)則

QQ|站長郵箱|小黑屋|手機版|Office中國/Access中國 ( 粵ICP備10043721號-1 )  

GMT+8, 2024-10-23 08:29 , Processed in 0.119644 second(s), 40 queries .

Powered by Discuz! X3.3

© 2001-2017 Comsenz Inc.

快速回復(fù) 返回頂部 返回列表